सवाल मैं एक बार में सभी पावरपॉइंट स्लाइड की भाषा कैसे बदलूं?


मैं पावरपॉइंट में अपनी सभी स्लाइडों की प्रूफिंग भाषा बदलना चाहता हूं। मैंने भाषा प्राथमिकता मेनू के माध्यम से भाषा सेट करने का प्रयास किया है, हालांकि यह केवल नए पावरपॉइंट्स के लिए इसे बदलता है।


133
2018-06-04 10:01


मूल


के संभावित डुप्लिकेट PowerPoint प्रस्तुति पर वर्तनी-जांच भाषा बदलें - sancho.s
ऐसा लगता है कि इस संबंध में पावरपॉइंट का नवीनतम संस्करण विशेष रूप से छोटी है। मेरे पास एक टेक्स्ट बॉक्स है जहां मैंने सभी टेक्स्ट की भाषा भाषा ए में बदल दी है। (डिफ़ॉल्ट भाषा बी है) इसलिए जब मैं उस टेक्स्ट बॉक्स में टाइप करना शुरू करता हूं, तो भाषा स्वचालित रूप से बी में बदल जाती है। मैंने सोचा कि शायद डिफ़ॉल्ट बदल रहा है भाषा मदद करता है (बाकी सब कुछ करने की कोशिश की) लेकिन नहीं। अब डिफ़ॉल्ट भाषा ए है, टेक्स्ट बॉक्स में अन्य सभी पाठों की भाषा ए है (और मैंने पीपी को पुनरारंभ किया है) लेकिन सभी नए टेक्स्ट अभी भी बी के रूप में दिखाई देते हैं। इसलिए मेरा एकमात्र शेष प्रश्न यह है: क्या सबूत स्विच करने का कोई तरीका है पूरी तरह से बंद? - lebatsnok
हां वर्तनी जांच को चालू करने का एक तरीका है: support.microsoft.com/en-us/help/937422/... - मेरी समस्या हल हो गई! - lebatsnok


जवाब:


मुझे पता है कि एक उत्तर पहले से ही स्वीकार कर लिया गया है, लेकिन यह केवल एक की प्रूफिंग भाषा बदलता है एक टेक्स्ट बॉक्स, और आपको मैन्युअल रूप से उन सभी को बदलने की आवश्यकता है।

की भाषा बदलने के लिए संपूर्ण पावरपॉइंट आसानी से खोलें राय टैब और चुनें रेखांकित करें राय।

अब दबाएं

  • Ctrl+ सभी का चयन करने के लिए।
  • उपकरण → भाषा → सेट करने के लिए अपनी भाषा चुनें।

इसी प्रकार जब आपके पास सब कुछ चुना गया है, तो आप फोंट, रंग इत्यादि जैसी अन्य चीजें बदल सकते हैं। बेशक कई मामलों में स्लाइड मास्टर को बदलकर बेहतर किया जाता है, एक प्रेजेंटेशन जिसमें कई संपादकों के पास बहुत सारे 'हार्ड' फॉर्मेटिंग सेट हो सकते हैं अंतर्निहित मास्टर से विचलित हो जाता है और लगातार होने के लिए रीसेट करने की आवश्यकता होती है। आप अलग-अलग स्लाइड को मास्टर स्टाइल में भी रीसेट कर सकते हैं, लेकिन इसके परिणामस्वरूप प्लेसहोल्डर भी आगे बढ़ सकते हैं, जो कुछ स्थितियों में अवांछनीय हो सकता है।

पावरपॉइंट 2013

  • राय → रेखांकित करें → के माध्यम से सभी स्लाइड (बाएं मेनू में) का चयन करें Ctrl+
  • समीक्षा → भाषा → प्रूफिंग भाषा सेट करें ... → सेट करने के लिए अपनी भाषा चुनें।

मेरे लिए - पावरपॉइंट पुनः आरंभ करें आवश्यकता थी। शायद क्योंकि मैंने भी बदल दिया था संपादन भाषा:

  • समीक्षा → भाषा → प्रूफिंग भाषा सेट करें ... → भाषा प्राथमिकताएं → संपादन भाषा चुनें

146
2018-03-17 17:29



उत्तर के लिए धन्यवाद, लेकिन भाषा बदलने के बाद, नया टाइप किया गया टेक्स्ट अभी भी पिछली भाषा में है (डिफ़ॉल्ट एक)। इसके अलावा, यदि आप मास्टर स्लाइड्स पर जाते हैं, तो चुनें स्लाइड, आप देखेंगे कि भाषा बार में भाषा अभी भी डिफ़ॉल्ट है, और इसे बदलने के लिए मेनू गहरा हुआ है। मुझे पागल हो रहा है कि माइक्रोसॉफ्ट द्वारा इतने सालों से हल नहीं किया गया है। - Endrju
बहुत बढ़िया! हालांकि सही नहीं है, यह निश्चित रूप से मदद करता है। मैं @ एन्ड्रजू से सहमत हूं, यह अभी तक तय क्यों नहीं है ?! - Mike
रिकॉर्ड के लिए, कार्यालय 2013 में, भाषा मेनू समीक्षा फलक में है (सेट प्रूफिंग भाषा) - Maria Ines Parnisari
पावरपॉइंट सिर्फ चौंकाने वाला बुरा है ना? जब मुझे इस तरह के मुद्दे हैं तो मैं वास्तव में खुले कार्यालय का उपयोग करना याद करता हूं। जैसे ही वे किसी वीडियो को सहेजने का समर्थन करते हैं, मैं कार्यालय खोलने के लिए वापस आऊंगा। - mjaggard
@Endrju आपको नए टाइप टेक्स्ट को नई भाषा में बनाने के लिए विंडोज टास्कबार में पावरपॉइंट के लिए भाषा बदलनी है। विवरण देखें मेरा जवाब। यह मुझे इतने लंबे समय के लिए बहुत परेशान किया ... - Gas


का उपयोग करते हुए पावरपॉइंट 2010 मैंने रूपरेखा मेनू खोला -

outline tab

सभी पाठ (Ctrl + A) चयनित, भाषा मेनू खोला और मेरी प्रूफिंग भाषा सेट करें

language option

और यह काम किया!

भाषा मेनू समीक्षा रिबन टैब पर स्थित है (स्लाइड शो टैब के बाद और स्क्रीनशॉट पर दिखाई नहीं दे रहा है)।


34
2018-06-04 10:01



केवल एक स्लाइड के लिए काम करता है - Helge Klein
यह मूल स्लाइड लेआउट के लिए काम करता है। यह पाठ बॉक्स के अंदर पाठ के लिए भाषा को बदल नहीं देगा या अन्य आकारों में घोंसला नहीं करेगा। - Duncan Jones
कार्यालय 2007 पर भी काम करता है। - Alfredo Osorio
ऑफिस मैक पर भी काम किया। - Jim McKeeth


मौजूदा उत्तर रूपरेखा में मौजूद पाठ के लिए काम करते हैं। दुर्भाग्य से मेरे मामले में इसने पाठ के एक महत्वपूर्ण भाग को शामिल नहीं किया, जिसमें आंकड़े, टेबल इत्यादि शामिल हैं।

इस मैक्रो ने मेरे लिए समस्या हल की:

 Sub ChangeProofingLanguageToEnglish()
    Dim j, k, m, scount, fcount, gcount As Integer
    scount = ActivePresentation.Slides.Count
    For j = 1 To scount
        fcount = ActivePresentation.Slides(j).Shapes.Count
        For k = 1 To fcount
            If ActivePresentation.Slides(j).Shapes(k).HasTextFrame Then
                ActivePresentation.Slides(j).Shapes(k) _
                .TextFrame.TextRange.LanguageID = msoLanguageIDEnglishUS
            End If
            If ActivePresentation.Slides(j).Shapes(k).Type = msoGroup Then
                gcount = ActivePresentation.Slides(j).Shapes(k).GroupItems.Count
                For m = 1 To gcount
                    If ActivePresentation.Slides(j).Shapes(k).GroupItems.Item(m).HasTextFrame Then
                    ActivePresentation.Slides(j).Shapes(k).GroupItems.Item(m) _
                    .TextFrame.TextRange.LanguageID = msoLanguageIDEnglishUS
            End If
                Next m
            End If
        Next k
    Next j
End Sub

उपरोक्त मैक्रो में "msoLanguageIDEnglishUS" का उपयोग किसी भी वांछित भाषा द्वारा प्रतिस्थापित किया जा सकता है। भाषाओं की पूरी सूची में पाया जा सकता है यह लेख

(क्रेडिट गणेश कुमार को जाता है जिन्होंने मूल मैक्रो पोस्ट किया था यहाँ। मैंने आकार समूह के पहले स्तर के लिए समर्थन जोड़ा। इसे और सुधारने के लिए मैक्रो को अन्य समूहों, आदि समूहों को देखने के लिए रिकर्सिव बनाया जा सकता है)


19
2017-08-09 08:11



+1 अच्छी शुरुआत। देख मेरा जवाब इस उत्तर के आधार पर एक पूरी तरह से रिकर्सिव संस्करण के लिए। - Duncan Jones


मैंने सुधार किया इनिगो का जवाब एक पुनरावर्ती संस्करण प्रदान करने के लिए जो सभी वस्तुओं को वांछित भाषा में बदल देता है।

यह संस्करण एक समूह प्रकार के प्रत्येक आकार की पुनरावृत्ति जांच करेगा। कुछ प्रयोगों से पता चलता है कि msoGroup तथा msoSmartArt समूह प्रकार हैं - यदि आप अन्य प्रकार के आकार टेक्स्ट ऑब्जेक्ट्स को पकड़ सकते हैं तो उस सूची में जोड़ने के लिए स्वतंत्र महसूस करें।

Sub ChangeProofingLanguageToEnglish()
    Dim j, k As Integer
    Dim languageID As MsoLanguageID

    'Set this to your preferred language
    languageID = msoLanguageIDEnglishUK

    For j = 1 To ActivePresentation.Slides.Count
        For k = 1 To ActivePresentation.Slides(j).Shapes.Count
            ChangeAllSubShapes ActivePresentation.Slides(j).Shapes(k), _
              languageID
        Next k
    Next j
End Sub


Sub ChangeAllSubShapes(targetShape As shape, languageID As MsoLanguageID)
    Dim i As Integer

    If targetShape.HasTextFrame Then
        targetShape.TextFrame.TextRange.languageID = languageID
    End If

    Select Case targetShape.Type
        Case msoGroup, msoSmartArt
            For i = 1 To targetShape.GroupItems.Count
                ChangeAllSubShapes targetShape.GroupItems.Item(i), languageID
            Next i
    End Select
End Sub

17
2017-11-25 09:52



ओएसएक्स पर PowerPoint 16.10 में इसे चलाने पर, मुझे मिलता है: Compile error: Method or data member not found - Etienne Low-Décarie


इनिगो, डंकन, मारिया और डोमडेव के उत्तरों के आधार पर, यह आकार, टेबल, समूह, स्मार्टआर्ट, अब और भविष्य में काम करता है:

Sub ChangeProofingLanguageToFrench()
    Dim j, k As Integer
    Dim languageID As MsoLanguageID

    'Set this to your preferred language
    languageID = msoLanguageIDFrench

    'Loop all the slides in the document, and change the language
    For j = 1 To ActivePresentation.Slides.Count
        For k = 1 To ActivePresentation.Slides(j).Shapes.Count
            ChangeAllSubShapes ActivePresentation.Slides(j).Shapes(k), languageID
        Next k
    Next j

    'Loop all the master slides, and change the language
    For j = 1 To ActivePresentation.SlideMaster.CustomLayouts.Count
        For k = 1 To ActivePresentation.SlideMaster.CustomLayouts(j).Shapes.Count
            ChangeAllSubShapes ActivePresentation.SlideMaster.CustomLayouts(j).Shapes(k), languageID
        Next k
    Next j

    'Change the default presentation language, so that all new slides respect the new language
    ActivePresentation.DefaultLanguageID = languageID
End Sub

Sub ChangeAllSubShapes(targetShape As Shape, languageID As MsoLanguageID)
    Dim i As Integer, r As Integer, c As Integer

    If targetShape.HasTextFrame Then
        targetShape.TextFrame.TextRange.languageID = languageID
    End If

    If targetShape.HasTable Then
        For r = 1 To targetShape.Table.Rows.Count
            For c = 1 To targetShape.Table.Columns.Count
                targetShape.Table.Cell(r, c).Shape.TextFrame.TextRange.languageID = languageID
            Next
        Next
    End If

    Select Case targetShape.Type
        Case msoGroup, msoSmartArt
            For i = 1 To targetShape.GroupItems.Count
                ChangeAllSubShapes targetShape.GroupItems.Item(i), languageID
            Next i
    End Select
End Sub

8
2017-07-09 09:41



अन्य समाधानों के लिए, ओएसएक्स पर PowerPoint 16.10 में इसे चलाने पर, मुझे मिलता है: Compile error: Method or data member not found। कोई सुझाया गया समाधान? यह हाइलाइट प्रतीत होता है .DefaultLanguageID। - Etienne Low-Décarie
@ एटियेनलो-डेकेरी: एपीआई पावरपॉइंट 16 में बदल सकता है; मेरे पास यह नहीं है इसलिए मैं जांच नहीं कर सकता, क्षमा करें। - tricasse


डंकन का संस्करण सब कुछ के लिए अच्छी तरह से काम करता है लेकिन टेबल। मुझे एक और कोड मिला जो टेबल के साथ भी काम करता है: https://stackoverflow.com/questions/4735765/powerpoint-2007-set-language-on-tables-charts-etc-that-contains-text 

Public Sub changeLanguage()
    On Error Resume Next
    Dim gi As GroupShapes '<-this was added. used below
    'lang = "English"
    lang = "Norwegian"
    'Determine language selected
    If lang = "English" Then
        lang = msoLanguageIDEnglishUK
    ElseIf lang = "Norwegian" Then
        lang = msoLanguageIDNorwegianBokmol
    End If
    'Set default language in application
    ActivePresentation.DefaultLanguageID = lang

    'Set language in each textbox in each slide
    For Each oSlide In ActivePresentation.Slides
        Dim oShape As Shape
        For Each oShape In oSlide.Shapes
            'Check first if it is a table
            If oShape.HasTable Then
                For r = 1 To oShape.Table.Rows.Count
                    For c = 1 To oShape.Table.Columns.Count
                    oShape.Table.Cell(r, c).Shape.TextFrame.TextRange.LanguageID = lang
                    Next
                Next
            Else
                Set gi = oShape.GroupItems
                'Check if it is a group of shapes
                If Not gi Is Nothing Then
                    If oShape.GroupItems.Count > 0 Then
                        For i = 0 To oShape.GroupItems.Count - 1
                            oShape.GroupItems(i).TextFrame.TextRange.LanguageID = lang
                        Next
                    End If
                'it's none of the above, it's just a simple shape, change the language ID
                Else
                    oShape.TextFrame.TextRange.LanguageID = lang
                End If
            End If
        Next
    Next End Sub

6
2018-05-22 13:36





द्वारा प्रदान किए गए उत्तर के अतिरिक्त Mastergalen और नए प्रकार के टेक्स्ट के बारे में टिप्पणियों को संबोधित करने के लिए:

यदि आप देखेंगे, जब भी आप नया टेक्स्ट टाइप करना शुरू करेंगे (वह बहुत परेशान है), तो आपको स्वचालित रूप से वापस बदलना होगा, आपको PowerPoint के लिए वर्तमान डिफ़ॉल्ट भाषा बदलनी होगी:

  • सुनिश्चित करें कि पावरपॉइंट विंडो एक सक्रिय विंडो है
  • में Windows Taskbar (हाँ, वास्तव में PowerPoint में नहीं), जांचें कि क्या Language bar दिख रहा है,
    • अगर नहीं जाना है Control Panel > Region and Language > Keyboards and Languages। क्लिक करें Change keybords..., पर स्विच Language bar टैब और जांचें Docked in the taskbar विकल्प। (यह Win7 से है, इसलिए अन्य संस्करणों में थोड़ा अलग हो सकता है)।
  • अब महत्वपूर्ण कार्रवाई - में Language bar टास्कबार में, भाषा कोड पर क्लिक करें और एन पर स्विच करें (यदि आप वर्तमान में पावरपॉइंट में अंग्रेजी का उपयोग करना चाहते हैं)। अब से, PowerPoint में सभी नए टेक्स्ट चयनित भाषा में होंगे :-)
  • अगर आप अपनी मूल भाषा में लिखना चाहते हैं, तो बस इसे वापस बदलें।

2
2017-07-04 12:52



हे भगवान, वे ऐसा कुछ क्यों करेंगे ?! धन्यवाद, पूरी तरह से काम किया। - Thibault D.
ठीक ठीक! स्वीकृत उत्तर में भी जोड़ा जाना चाहिए। - Abdelhafid Madoui
लेकिन यह कुंजीपटल लेआउट भी बदलता है, है ना? ... मैं अंग्रेजी पाठ टाइप करना चाहता हूं लेकिन मैं वास्तव में अपना जर्मन कीबोर्ड लेआउट रखना चाहता हूं .... - Johannes S.
@JohannesS। यदि आप राइट क्लिक करते हैं En टास्क बार में और चुनें Settings.. यदि आप अंग्रेजी का विस्तार करते हैं, तो आप स्थापित भाषाओं जर्मन (डीई) और अंग्रेजी (एन) में देखेंगे, वहां होगा Keyboards सूचीबद्ध, कीबोर्ड का विस्तार करें, और अपना पसंदीदा जर्मन कीबोर्ड जोड़ें, शायद अंग्रेजी को भी हटा दें। मैंने कोशिश नहीं की, लेकिन सिद्धांत में काम करना चाहिए ;-) - Gas